# SPDX-License-Identifier: BSD-2-Clause
# SPDX-FileCopyrightText: 2026 pluvium27 <pluvium27@outlook.com>

add_subdirectory(settings)

qt_add_library(kirimemo_static STATIC)
ecm_add_qml_module(kirimemo_static
    URI org.kde.kirimemo
    GENERATE_PLUGIN_SOURCE
    QML_FILES
        qml/Main.qml
    DEPENDENCIES
        org.kde.kirigamiaddons.formcard
        org.kde.kirigamiaddons.statefulapp
        org.kde.kirigami
        org.kde.kirimemo.settings
)

target_sources(kirimemo_static PRIVATE
    kirimemoapplication.cpp
    kirimemoapplication.h
)

target_link_libraries(kirimemo_static PUBLIC
    Qt6::Quick
    KF6::I18n
    KF6::CoreAddons
    KF6::ConfigGui
    KirigamiAddonsStatefulApp
)
target_include_directories(kirimemo_static PUBLIC ${CMAKE_BINARY_DIR})

if (ANDROID)
    kirigami_package_breeze_icons(ICONS
        list-add
        help-about
        application-exit
        applications-graphics
    )
else()
    target_link_libraries(kirimemo_static PUBLIC
        Qt::Widgets
        KF6::I18nQml
    )
endif()

kconfig_add_kcfg_files(kirimemo_static GENERATE_MOC kirimemoconfig.kcfgc)

add_executable(kirimemo main.cpp)
target_link_libraries(kirimemo PUBLIC
    KirigamiApp
    kirimemo_static
    kirimemo_staticplugin
    kirimemo_settings
    kirimemo_settingsplugin
)
install(TARGETS kirimemo ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
ecm_add_android_apk(kirimemo ANDROID_DIR ${CMAKE_SOURCE_DIR}/android)
